; Module/File:     LIG_HeaderVisibility.pb
; Function:        Query and switches the visibility of the header on and off. - Linux
; Author:          Omi
; Date:            Nov. 27, 2018
; Version:         0.1
; Target Compiler: PureBasic 5.22/5.31/5.4x/5.6/5.7
; Target OS:       Linux: (X/K/L)ubuntu, Mint, 32/64, Ascii/Uni
;--------------------------------------------------------------


EnableExplicit

;Object constants
#Win_Main= 0

#LIG   = 0
#But   = 1

Global.i gEvent, gQuit


Procedure CreateWindow_Main()
	Protected.i I, O

	If OpenWindow(#Win_Main, 200, 200, 500, 400, "LIG header visibility", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
		ButtonGadget  (#But,   5,   5, 490,  26, "ListIcon-Header visibility", #PB_Button_Toggle)
		ListIconGadget(#LIG,   5,  35, 490, 350, "column 0", 90, #PB_ListIcon_AlwaysShowSelection)
		
		For O= 1 To 4
			AddGadgetColumn(#LIG, O, "column " + Str(O), 90)
		Next O
		For I= 0 To 19
			AddGadgetItem(#LIG, -1, Str(I) + ".0")
			For O= 1 To 4
				SetGadgetItemText(#LIG, I, Str(I) + "." + Str(O), O)
			Next O
		Next I
		
		;gtk_tree_view_get_headers_visible_(*tree_view.GtkTreeView); Get visibility state: returns visible = 1, invisible = 0
		SetGadgetState(#But, gtk_tree_view_get_headers_visible_(GadgetID(#LIG))); query headers visibility and sets the button state
	EndIf
EndProcedure

CreateWindow_Main()

Repeat
	gEvent= WaitWindowEvent()

	Select gEvent
		Case #PB_Event_CloseWindow
			gQuit= #True
			
		Case #PB_Event_Gadget
			If EventGadget() = #But
				;gtk_tree_view_set_headers_visible_(*tree_view.GtkTreeView, gboolean headers_visible); visible = 1, invisible = 0
				gtk_tree_view_set_headers_visible_(GadgetID(#LIG), GetGadgetState(#But))
			EndIf
	EndSelect
	
Until gQuit
; IDE Options = PureBasic 5.62 (Linux - x86)
; CursorPosition = 23
; Folding = -
; EnableXP
; SubSystem = gtk2